Интеграл и график в любой версии Pascal, Maple. Что-либо другое - Страница 2

Vladimir_S · 20.05.2015, 14:20

Цитата:

Сообщение от Dimafania

Владимир, вынужден снова обратиться к вам за помощью.

Пожалуйста, чем, как говорится, могу.

Цитата:

Сообщение от Dimafania

К сожалению написанная мною программа выдает какую-то ерунду.

Это нормально. Так всегда бывает у начинающих программистов.

Цитата:

Сообщение от Dimafania

Ниже приведу вам текст, может быть вы увидите какую-нибудь глупость.

Сначала я напишу свой вариант, а Вы посмотрите.

Цитата:

Сообщение от Dimafania

Перед тем как приведу вам текст, хочу обратить внимание, что файл я переименовал в Zr.txt, а также оставил там только значения g(w), удалив значения w.

Вот уж совсем не могу понять - зачем? Ведь шкала частот - неравномерная!
P.S. Какие-то странные у Вас значения K и ħ. Это в каких единицах?

Dimafania · 20.05.2015, 14:38

Шкалу частот я принял равномерно увеличивающейся с шагом 0.033E12.
Постоянную Больцмана брал в эВ*К^-1
Планка эВ*с
Подбирал размерности таким образом, чтобы гиперболический синус был безразмерным.

Vladimir_S · 20.05.2015, 15:02

Цитата:

Сообщение от Dimafania

Шкалу частот я принял равномерно увеличивающейся с шагом 0.033E12.
Постоянную Больцмана брал в эВ*К^-1
Планка эВ*с
Подбирал размерности таким образом, чтобы гиперболический синус был безразмерным.

Значит, так, сударь.
Написал я программку и прокрутил.
Вот:

Код:

Const
 h=6.582119E-16;
 K=8.6173324E-5;
 N=239;

Var
 t:text;
 w,g:Array [1..239] of real;
 i,Tem:integer;

Function Sh(r:real):real;
begin
 Sh:=(Exp(r)-Exp(-r))/2;
end;

Function F(v,T:real):real;
begin
 F:=K*Sqr(h*v/(K*T*2))/Sqr(Sh(h*v/(K*T*2)));
end;

Function Cv(T:real):Real;
var
 Sum:Real;
 j:Integer;
begin
 Sum:=0;
 for j:=1 to N-1 do
  Sum:=Sum+F((w[j+1]+w[j])/2,T)*(g[j+1]+g[j])/2*(w[j+1]-w[j]);
 Cv:=Sum;
end;

begin
 Assign(t,'D:\g.txt');
 Reset(t);
 Readln(t);
 for i:=1 to N do readln(t,w[i],g[i]);
 Close(t);
 Assign(t,'D:\res.txt');
 Rewrite(t);
 for Tem:=1 to 10 do
  Writeln(t,Tem:3,'     ',Cv(1.0*Tem));
 Close(t)
End.

Пояснения: исходный файл g.txt я оставил, как был. Выходные данные отправил в файл Res.txt. Оба файла у меня расположены на диске D: (эту уж мне так удобно; Вы поставьте по-своему). В результате получил практически константу, что немудрено: аргумент гиперболического синуса имеет порядок 10^-10, а это значит, что гиперболический синус можно заменить самим аргументом, в результате чего в подынтегральном выражении функция F становится просто равной К, чего быть не должно.
Вывод: что-то напортачено с единицами в константах. Сейчас попробую разобраться.

Vladimir_S · 20.05.2015, 15:15

А, нет, прошу прощения - отбой! Константы поставлены правильно, проверил. Это просто я чудак на букву "м" - забыл домножить частоту на 10^12. Если это сделать, получается вполне разумно. Вот исправленный текст:

Код:

Const
 h=6.582119E-16;
 K=8.6173324E-5;
 N=239;

Var
 t:text;
 w,g:Array [1..239] of real;
 i,Tem:integer;

Function Sh(r:real):real;
begin
 Sh:=(Exp(r)-Exp(-r))/2;
end;

Function F(v,T:real):real;
begin
 F:=K*Sqr(h*v/(K*T*2))/Sqr(Sh(h*v/(K*T*2)));
end;

Function Cv(T:real):Real;
var
 Sum:Real;
 j:Integer;
begin
 Sum:=0;
 for j:=1 to N-1 do
  Sum:=Sum+F((w[j+1]+w[j])/2,T)*(g[j+1]+g[j])/2*(w[j+1]-w[j]);
 Cv:=Sum;
end;

begin
 Assign(t,'D:\g.txt');
 Reset(t);
 Readln(t);
 for i:=1 to N do
  begin
   readln(t,w[i],g[i]);
   w[i]:=w[i]*1E12;
  end;
 Close(t);
 Assign(t,'D:\res.txt');
 Rewrite(t);
 for Tem:=1 to 10 do
  Writeln(t,Tem:3,'     ',Cv(1.0*Tem));
 Close(t)
End.

Dimafania · 20.05.2015, 16:18

Спасибо, Владимир. Сейчас буду списывать вашу программу и проверять) Интересно, что я попробовал на пальцах проверить свою программу (только интеграл взял полегче, чтоб вручную подсчитать), и вроде бы все работает. А с изначальным интегралом брехня получается=)

Dimafania · 20.05.2015, 16:32

Цитата:

Сообщение от Vladimir_S

Sum:=Sum+F((w[j+1]+w[j])/2,T)*(g[j+1]+g[j])/2*(w[j+1]-w[j]);

Владимир, а в этой строчке множитель (w[j+1]-w[j]) не уходит случайно к двойке в знаменатель? Скобками не надо выделять?

Vladimir_S · 20.05.2015, 16:47

Цитата:

Сообщение от Dimafania

Владимир, а в этой строчке множитель (w[j+1]-w[j]) не уходит случайно к двойке в знаменатель? Скобками не надо выделять?

Нет. В Паскале (да и, по-моему, в любом ЯП) умножение и деление имеют равный приоритет, и цепочка вида a*b/c/d*e означает: a умножается на b, результат делится на c, результат делится на d, результат умножается на e.

Vladimir_S · 20.05.2015, 16:51

Для пущей наглядности: программа

Код:

Begin
 Writeln(2*3/2*3);
 Readln
End.

выдает в результате 9, а не 1. Можете проверить.

Dimafania · 20.05.2015, 18:16

Еще раз спасибо, Владимир. Программа ваша работает прекрасно. Буду разбираться с полученными цифрами, а точнее степенями.

Dimafania · 21.05.2015, 14:49

Цитата:

Сообщение от Vladimir_S

Writeln(t,Tem:3,' ',Cv(1.0*Tem));

Добрый день, Владимир. Не могли бы вы пояснить эту строчку? Точнее член Cv(1.0*Tem)? А еще точнее вот этот момент 1.0*Tem? Значение теплоемкости емкости умножается на значение температуры?

20.05.2015, 15:15	#14 (permalink)
Vladimir_S Специалист Регистрация: 27.08.2008 Адрес: Санкт-Петербург Сообщений: 27,807 Сказал(а) спасибо: 340 Поблагодарили 583 раз(а) в 208 сообщениях Репутация: 113184	А, нет, прошу прощения - отбой! Константы поставлены правильно, проверил. Это просто я чудак на букву "м" - забыл домножить частоту на 10^12. Если это сделать, получается вполне разумно. Вот исправленный текст: Код: Const h=6.582119E-16; K=8.6173324E-5; N=239; Var t:text; w,g:Array [1..239] of real; i,Tem:integer; Function Sh(r:real):real; begin Sh:=(Exp(r)-Exp(-r))/2; end; Function F(v,T:real):real; begin F:=KSqr(hv/(KT2))/Sqr(Sh(hv/(KT2))); end; Function Cv(T:real):Real; var Sum:Real; j:Integer; begin Sum:=0; for j:=1 to N-1 do Sum:=Sum+F((w[j+1]+w[j])/2,T)(g[j+1]+g[j])/2(w[j+1]-w[j]); Cv:=Sum; end; begin Assign(t,'D:\g.txt'); Reset(t); Readln(t); for i:=1 to N do begin readln(t,w[i],g[i]); w[i]:=w[i]1E12; end; Close(t); Assign(t,'D:\res.txt'); Rewrite(t); for Tem:=1 to 10 do Writeln(t,Tem:3,' ',Cv(1.0*Tem)); Close(t) End.

20.05.2015, 16:51	#18 (permalink)
Vladimir_S Специалист Регистрация: 27.08.2008 Адрес: Санкт-Петербург Сообщений: 27,807 Сказал(а) спасибо: 340 Поблагодарили 583 раз(а) в 208 сообщениях Репутация: 113184	Для пущей наглядности: программа Код: Begin Writeln(23/23); Readln End. выдает в результате 9, а не 1. Можете проверить.

20.05.2015, 14:38	#12 (permalink)
Dimafania Member Регистрация: 18.05.2015 Сообщений: 29 Сказал(а) спасибо: 0 Поблагодарили 0 раз(а) в 0 сообщениях Репутация: 10	Шкалу частот я принял равномерно увеличивающейся с шагом 0.033E12. Постоянную Больцмана брал в эВК^-1 Планка эВс Подбирал размерности таким образом, чтобы гиперболический синус был безразмерным.

20.05.2015, 16:18	#15 (permalink)
Dimafania Member Регистрация: 18.05.2015 Сообщений: 29 Сказал(а) спасибо: 0 Поблагодарили 0 раз(а) в 0 сообщениях Репутация: 10	Спасибо, Владимир. Сейчас буду списывать вашу программу и проверять) Интересно, что я попробовал на пальцах проверить свою программу (только интеграл взял полегче, чтоб вручную подсчитать), и вроде бы все работает. А с изначальным интегралом брехня получается=)

Ads
Яндекс Member Регистрация: 31.10.2006 Сообщений: 40200 Записей в дневнике: 0 Сказал(а) спасибо: 0 Поблагодарили 0 раз(а) в 0 сообщениях Репутация: 55070

20.05.2015, 18:16	#19 (permalink)
Dimafania Member Регистрация: 18.05.2015 Сообщений: 29 Сказал(а) спасибо: 0 Поблагодарили 0 раз(а) в 0 сообщениях Репутация: 10	Еще раз спасибо, Владимир. Программа ваша работает прекрасно. Буду разбираться с полученными цифрами, а точнее степенями.