Технический форум
Вернуться   Технический форум > Программирование > Форум программистов > Помощь студентам


Ответ
 
Опции темы Опции просмотра
Старый 08.06.2010, 12:22   #1 (permalink)
VinneyPooh
Новичок
 
Регистрация: 08.06.2010
Сообщений: 4
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 10
По умолчанию Задание на массивы из ЕГЭ Блок C-4 (pascal abc)

Задача: Нужно из программы, которая написана в строках сделать идентичную, которая будет написана в виде записей.
p.s. и если не затруднит, напишите пару объяснений, что откуда берется, как в приведенной в строках программе.

ТЕКСТ ЗАДАЧИ
На вход программе сначала подается число участников олимпиады N. В каждой из следующих N строк находится результат одного из участников олимпиады в следующем формате:
<Фамилия> <Имя> <класс> <баллы>
где <Фамилия> – символьная строка (не более 20 символов), <Имя> – символьная строка (не более 15 символов), <класс> – число от 7 до 11, <баллы> – целое число набранных участником баллов. <Фамилия> и <Имя>, <Имя> и <класс>, а также <класс> и <баллы> разделены одним пробелом. Пример входной строки:
Семенов Егор 11 225
Победителем олимпиады становится участник, набравший наибольшее количество баллов, при условии, что он набрал более 200 баллов. Если такое количество баллов набрали несколько участников, то все они признаются победителями при выполнении условия, что их доля не превышает 20% от общего числа участников.
Победителем олимпиады не признается никто, если нет участников, набравших больше 200 баллов, или больше 20% от общего числа участников набрали одинаковый наибольший балл.
Напишите эффективную по времени работы и по используемой памяти программу, которая будет определять фамилию и имя лучшего участника, не ставшего победителем олимпиады. Если таких участников несколько, т.е. если следующий за баллом победителей один и тот же балл набрали несколько человек, или, если победителей нет, а лучших участников несколько (в этом случае именно они являются искомыми), то выдается только количество искомых участников. Гарантируется, что искомые участники (участник) имеются.
Программа должна выводить через пробел фамилию и имя искомого участника или их количество. Пример выходных данных (один искомый участник):
Семенов Егор
Второй вариант выходных данных (несколько искомых участников):
12

МАТЕМАТИЧЕСКАЯ МОДЕЛЬ
План:
Нужно вычленить из условия существенные моменты:
• нужные нам участники получили наибольший балл, если нет победителей или второй по величине, если победители есть, участники с более низкими баллами нас не интересуют;
• нужно хранить имя только одного из искомых участников, а не всех;
• класс нас не интересует.
Нужно определить:
• количество участников, получивших высший балл, и имя одного из них;
• количество участников, получивших второй по величине балл, и имя одного из них;

Программа в строках:

Код:
var ballBest: array[1..2] of integer;   {результат (баллы)}
    numBest: array[1..2] of integer;    {количество}
    nameBest: array[1..2] of string;    {имена}
    N: integer;                         {число участников} 
    c: char;                            {символ для ввода}
    i, j, k, ball: integer;                     {вспомогательные переменные}
    name: string;
begin
  Readln(N);                            {ввод числа участников}
  ballBest[1] := -1;                    {начальное значение, < 0}
  for i:=1 to N do begin
       name := '';                              {читаем фамилию и имя}
    for j:=1 to 2 do
      repeat 
        read(c); 
        name := name + c; 
      until c = ' ';
    read(k);                            {пропускаем класс}
    readln(ball);                       {читаем баллы участника}
       if ball > ballBest[1] then begin {обрабатываем баллы} {новый участник набрал больше баллов, чем все предыдущие}
      ballBest[2] := ballBest[1];       {копируем все 1-ые элементы массивов во 2-ые} 
      numBest[2] := numBest[1];         
      nameBest[2] := nameBest[1];
      ballBest[1] := ball;              {в 1-ые записываем данные нового участника (имя, баллы, количество = 1)}
      numBest[1] := 1;     
      nameBest[1] := name;
    end
    else  
      if ball = ballBest[1] then                {новый участник набрал столько же баллов, сколько лучшие из предыдущих - нужно увеличить их количество на 1}
        numBest[1] := numBest[1] + 1
      else
        if ball > ballBest[2] then begin {новый участник набрал второе количество баллов - нужно во 2-ые элементы массивов записать данные нового участника (имя, баллы, количество = 1)}
          ballBest[2] := ball;
          numBest[2] := 1;     
          nameBest[2] := name;
        end
        else  
          if ball = ballBest[2] then {новый участник набрал столько же баллов, сколько участники с вторым известным ранее результатом; нужно увеличить их количество на 1}
            numBest[2] := numBest[2] + 1;    
  end;
    if (ballBest[1] > 200) and (numBest[1]*100 <= N*20) then {определяем, есть ли победители}
       i := 2
  else i := 1;
  if numBest[i] > 1 then                {выводим результат}
       writeln(numBest[i])
  else writeln(nameBest[i]);
end.
VinneyPooh вне форума   Ответить с цитированием

Старый 08.06.2010, 12:22
Helpmaster
Member
 
Аватар для Helpmaster
 
Регистрация: 08.03.2016
Сообщений: 0

Пока вам дают ответы вы можете почитать похожие темы

Двумерные массивы и процедуры PASCAL
Задание в Pascal. Подскажите
Pascal массивы
Задача на массивы, Pascal. Помогите найти ошибку
Массивы Pascal
Помогите с блок-схемой Turbo-Pascal

Старый 08.06.2010, 14:06   #2 (permalink)
Vladimir_S
Специалист
 
Регистрация: 27.08.2008
Адрес: Санкт-Петербург
Сообщений: 27,807
Сказал(а) спасибо: 340
Поблагодарили 583 раз(а) в 208 сообщениях
Репутация: 113184
По умолчанию

Вот, что-то нарисовал. Не могу гарантировать, что программа так уж абсолютно оптимизирована, но чем богаты.
Код:
Type Participant=Record
            Surname:String;
            Name:String;
            Class:Byte;
            Balls:Word;
           End;
var
 N:BYTE;
 Prt:Array[1..25] of Participant;
 Num_first,Num_Second:Array[1..25] of Byte;
 Ball:Array[1..25] of WORD;
 Ball_first,Ball_second:WORD;
 N_first, N_second:BYTE;
 i,j:Integer;
begin
{Ввод исходных данных по участникам}
 Write('Enter the number of participants (<26) ');
 ReadLn(N);
 For i:=1 to N do
  With Prt[i] do
   begin
    WriteLn('Surname (max 20 symbols)');
    ReadLn(Surname);
    WriteLn('Name (max 15 symbols)');
    ReadLn(Name);
    Write('Class ');
    ReadLn(Class);
    Write('Balls ');
    ReadLn(Balls);
    WriteLn;
   end;

{Поиск высшего балла}
 Ball_First:=0;
 For i:=1 to N do
  With Prt[i] do
   If Balls>Ball_First then Ball_First:=Balls;

{Поиск количества участников, имеющих высший балл, и их порядковых номеров в списке}
 N_first:=0;
 For i:=1 to N do
  With Prt[i] do
   If Balls=Ball_First then
    begin
     Inc(N_first);
     Num_first[N_first]:=i;
    end;

{Поиск второго по величине балла}
 Ball_Second:=0;
 For i:=1 to N do
  With Prt[i] do
   If (Balls>Ball_Second) and (Balls<Ball_First) then Ball_Second:=Balls;

{Поиск количества участников, имеющих второй балл, и их порядковых  номеров в списке}
 N_Second:=0;
 For i:=1 to N do
  With Prt[i] do
   If Balls=Ball_Second then
    begin
     Inc(N_Second);
     Num_Second[N_Second]:=i;
    end;

{Вывод информации}
 WriteLn('Winners:');
 If (Ball_First<200) or (1.0*N_first/N>0.2) then
  begin
   WriteLn('None');
   WriteLn;
   WriteLn('Best:');
   If N_first=1 then
    WriteLn(Prt[Num_First[1]].Surname+' '+Prt[Num_First[1]].Name) else
   WriteLn(N_First);
  end else
 If (Ball_First>=200) and (1.0*N_first/N<=0.2) then
  begin
   For i:=1 to N_first do
    WriteLn(Prt[Num_First[i]].Surname+' '+Prt[Num_First[i]].Name);
   WriteLn;
   WriteLn('Second:');
   If N_Second>1 then WriteLn(N_Second);
   WriteLn(Prt[Num_Second[1]].Surname+' '+Prt[Num_Second[1]].Name);
  end;
 ReadLn;
end.
Vladimir_S вне форума   Ответить с цитированием
Старый 08.06.2010, 14:32   #3 (permalink)
VinneyPooh
Новичок
 
Регистрация: 08.06.2010
Сообщений: 4
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 10
По умолчанию

Спасибо Вам огромнейшее за помощь

сначала Pascal ABC ругался на четвертую строку в вашей программе: "Class:Byte;", я исправил Class на Clas, вроде пошло...
VinneyPooh вне форума   Ответить с цитированием
Старый 08.06.2010, 14:35   #4 (permalink)
Vladimir_S
Специалист
 
Регистрация: 27.08.2008
Адрес: Санкт-Петербург
Сообщений: 27,807
Сказал(а) спасибо: 340
Поблагодарили 583 раз(а) в 208 сообщениях
Репутация: 113184
По умолчанию

Цитата:
Сообщение от VinneyPooh Посмотреть сообщение
Спасибо Вам огромнейшее за помощь

сначала Pascal ABC ругался на четвертую строку в вашей программе: "Class:Byte;", я исправил Class на Clas, вроде пошло...
Интересно. Вероятно, в АВС это служебное слово. Мой Паскаль жрет этот Class и не давится.
Vladimir_S вне форума   Ответить с цитированием
Старый 08.06.2010, 14:39   #5 (permalink)
MrSTEP
一步一步地会到目的
 
Аватар для MrSTEP
 
Регистрация: 09.05.2009
Адрес: Черноземье
Сообщений: 10,939
Записей в дневнике: 10
Сказал(а) спасибо: 140
Поблагодарили 80 раз(а) в 33 сообщениях
Репутация: 28362
По умолчанию

ABC Pascal весьма интересный язык. В нем, например, цикл
while (условие) do begin
Оператор1;
Оператор2;
...
end;

не работают, и еще замечали какие-то косяки с ним
MrSTEP вне форума   Ответить с цитированием
Ads

Яндекс

Member
 
Регистрация: 31.10.2006
Сообщений: 40200
Записей в дневнике: 0
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 55070
Старый 08.06.2010, 14:49   #6 (permalink)
VinneyPooh
Новичок
 
Регистрация: 08.06.2010
Сообщений: 4
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 10
По умолчанию

мне тоже показалось, что это, возможно, какая-то переменная, т.к. цвет у Class отличался от Surname, Name, Balls. Но сейчас то, главное, всё работает спасибо вам ещё раз не каждый человек способен помочь, как Вы Vladimir_S!
VinneyPooh вне форума   Ответить с цитированием
Старый 08.06.2010, 14:53   #7 (permalink)
VinneyPooh
Новичок
 
Регистрация: 08.06.2010
Сообщений: 4
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 10
По умолчанию

Цитата:
Сообщение от MrSTEP Посмотреть сообщение
ABC Pascal весьма интересный язык. В нем, например, цикл
while (условие) do begin
Оператор1;
Оператор2;
...
end;

не работают, и еще замечали какие-то косяки с ним
уж очень интересный ещё так же бывает, что одна программа будет в одной версии дистрибутива работать, а в другой уже не будет.
VinneyPooh вне форума   Ответить с цитированием
Ads

Яндекс

Member
 
Регистрация: 31.10.2006
Сообщений: 40200
Записей в дневнике: 0
Сказал(а) спасибо: 0
Поблагодарили 0 раз(а) в 0 сообщениях
Репутация: 55070
Ответ

Опции темы
Опции просмотра

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Выкл.
HTML код Выкл.
Trackbacks are Вкл.
Pingbacks are Вкл.
Refbacks are Выкл.




Часовой пояс GMT +4, время: 03:09.

Powered by vBulletin® Version 6.2.5.
Copyright ©2000 - 2014, Jelsoft Enterprises Ltd.